Sub TabulkaTextoveProDBF()
 
   Dim Oblast As Range
   Dim Sloupec As Range
   Dim Radek As Range
   Dim Bunka As Range
   Dim Ret As String
   Dim Retezec As String
   Dim RetezecOddel As String
   Dim i As Integer
   Dim j As Integer
   Dim PocetRadku As Integer
   Dim PocetSloupcu As Integer
   Dim PoleDelky()
 
   'nastavení vstupní oblasti
   Set Oblast = Selection
 
   PocetRadku = Oblast.Rows.Count
   PocetSloupcu = Oblast.Columns.Count
 
   ReDim PoleDelky(1 To PocetSloupcu)
 
   RetezecOddel = "+"
 
   'zjištění maximální délky obsahu buňky ve sloupci
   'a sestavení řetězce oddělujícího řádku
   For Each Sloupec In Oblast.Columns
      i = i + 1
      Maximum = Len(Sloupec.Cells(1).Text)
      For Each Bunka In Sloupec.Cells
         Maximum = WorksheetFunction.Max(Maximum, Len(Bunka.Text))
      Next Bunka
      PoleDelky(i) = Maximum
      RetezecOddel = RetezecOddel & String(Maximum, "-") & "+"
   Next Sloupec
 
   Retezec = "|"
 
   'sestavení jednotlivých řádků
   For Each Radek In Oblast.Rows
      For Each Bunka In Radek.Cells
         j = j + 1
         Ret = Ret & Bunka.Text & Space(PoleDelky(j) - Len(Bunka.Text)) & "|"
      Next Bunka
      Retezec = Retezec & Ret & vbCrLf & RetezecOddel & vbCrLf & "|"
      j = 0
      Ret = ""
   Next Radek
 
   'včetně ohraničení shora
   'Retezec = RetezecOddel & vbCrLf & Left(Retezec, Len(Retezec) - 3)
   Retezec = Left(Retezec, Len(Retezec) - 3)
 
   Debug.Print Retezec
 
End Sub